chris

I just wrote an AppleScript for setting the status on Adium using Quicksilver. It’s dedicated to usage with FriendFeed, which I recently registered at. It’s not something new (read below) but at least this works.

Here goes:

using terms from application "Quicksilver"
  on process text ThisClipping
    tell application "Adium"
      if (ThisClipping is not "" and ¬
        (first character of ThisClipping is "/")) then
        set theCommand to first word of ThisClipping as text

        if (theCommand is "o" or ¬
          theCommand is "off" or ¬
          theCommand is "offline") then
          go offline
        else if (theCommand is "i" or ¬
          theCommand is "invis" or ¬
          theCommand is "invisible") then
          go invisible
        else if (theCommand is "a" or ¬
          theCommand is "away") then
          if ((count words of ThisClipping) is 1) then
            go away
          else
            go away with message ¬
              (texts (offset of (word 2 of ThisClipping) in ThisClipping) ¬
                thru -1 of ThisClipping)
          end if
        end if
      else
        go available with message ThisClipping
      end if
    end tell
  end process text
end using terms from

This was written after referring to these two blog entries. (I didn’t even bother changing the ThisClipping variable name, as you can see.)
Paste the code into Script Editor. As written in the first blog entry I’ve mentioned, you can save this in “~/Library/Application Support/Quicksilver/Actions“. If the directory doesn’t exist, just create it. And restart QuickSilver after that.

I named my script “Adium Status.scpt”, so I could use it after typing “A” and “S”. (of course, I could also type “status”, or whatever.)

Features:

• “/a”, “/away” changes your status to Away
• “/i”, “/invis”, “/invisible” changes your status to Invisible
• “/o”, “/off”, “/offline” tells Adium to go Offline

You could type “/a Something” and your status will be set to Away with a custom status message of “Something”.
Your custom status message is set leaving your Status as Available on default.
The custom status message only works with the Away command because you can’t have status messages while you’re Invisible or Offline. (duh)
This is tested with the latest 1.3b5 beta of Adium and latest build of Quicksilver.

Tags: adium, applescript, friendfeed, quicksilver

This entry was posted on Tuesday, July 1st, 2008 at 10:24 am and is filed under Desktop, Tech. You can follow any responses to this entry through the RSS 2.0 feed. You can leave a response, or trackback from your own site.